Dateien umbenennen mit Hilfe einer Excel-Tabelle

tony_danza

Hallo Hans,

vielen Dank für deine Erklärung.

Diesen Umweg gehe ich ja nur, weil ich mir nicht anders zu helfen weiss.

Manchmal ist es aber auch nur ein kleines Wort was den Unterschied macht. Man muss es aber wissen bzw. kennen.
Mir war es nicht bekannt :)

Aber danke für diesen Hinweis!

Okay Hans, dann wünsch ich dir mal einen schönen Nachmittag und bin gespannt von dir zu hören.

viele Grüße
tony

Hans_Haesler

Hallo Tony,

heute ist wieder allerlei Unvorhergesehenes dazwischengekommen. Das Script ist noch nicht fertig.
Ich habe Dir einen Link zum Herunterladen der Betaversion 04 geschickt.

Nach dem Droppen der Dateien sollte ein Dialog die Farben zur Auswahl anbieten.
Einen der angezeigten Namen wählen und auf "OK" klicken. Ein Dialog meldet den gewählten Namen.
Würdest Du bitte prüfen, ob das bei Dir auch funktioniert.

Im Laufe des Donnerstags werde ich versuchen, diese erste Version fertigzustellen.

Gruss, Hans

Hans_Haesler

Hallo Tony,

endlich ... ist die erste Version fertig.

Ich habe Dir per E-Mail den Link zum Herunterladen zugestellt.

Nun hoffe ich, dass das Droplet schon wie erwartet funktionieren wird.

Gruss, Hans

tony_danza

Hallo Hans,

ich habe deine Mail gesehen und vielen Dank für diese Version!
Funktioniert bei mir reibungslos und schnell ;)

Wie ich bereits in der Mail geschrieben habe, gebe ich dir am Montag bescheid wie das Script mit Dataien auf dem Server umgeht.

Bis dahin ein schönes Wochenende!

viele Grüße
tony

Hans_Haesler

Hallo Tony,

ich bedanke mich für Deine positive Rückmeldung. Super, dass es auf Anhieb funktioniert!

Ich werde morgen noch das Sortieren der Farbnamen einbauen. Und prüfen, ob sich Dateien, welche auf einem Server liegen, umbenennen lassen.

Gruss, Hans

Hans_Haesler

Hallo Tony,

ich habe Dir per E-Mail den Link zum erweiterten Droplet zugestellt.

Nun werden die Farbnamen sortiert. Das besorgt der Handler 'quickSort()'.

Den Test mit dem Server habe ich gemacht. Der Server ist gut zwei Kilometer entfernt. Habe mich per VPN mit einem Laptop eingeloggt, ein paar Dateien in einen Testordner kopiert.

Dann die Dateien auf das Droplet gezogen. Ergebnis: alle wurden umbenannt. Keine Probleme.

Gruss, Hans

tony_danza

Hallo Hans,

das Script funktioniert bestens :)

Sortierte Farbnamen macht es auf jeden Fall übersichtlicher und einfacher zum auswählen.

Ich bin wirklich gespannt wie sich das Script in der Praxis mit Dateien auf dem Server verhält. Mehr dazu dann morgen ;) Ich werde berichten!
Aber schon mal gut, dass das ohne Probleme bei dir funktioniert.

Danke für diese Modifizierung im Script.

Gruß
tony

Hans_Haesler

Hallo Tony,

danke für Deine Bestätigung. Ich hoffe sehr, dass es bei Dir mit dem Server ebenfalls klappen wird.

Auf Deinen Wunsch ist das Droplet (samt Testdateien) bereit zum Veröffentlichen.
Aber ich warte noch Deinen Praxis-Bericht ab.

Gruss, Hans

tony_danza

Hallo Hans,

das Script funktioniert wunderbar! Ohne Probleme und rasend schnell.

Alle Dateien werden auf dem Server umbenannt.

Ich denke es ist nun an der Zeit das Script hier zu veröffentlichen (samt Testdateien).

Vielen Dank Hans für deinen Einsatz. Das Script ist mehr als gelungen ;) Genau so habe ich mir das gewünscht.

viele Grüße
tony

Hans_Haesler

Hallo Tony,

bitte sehr. Super, dass es jetzt auch mit Dateien auf dem Server klappt.

Dein Wunsch ist mein Befehl :-). Der Code ist am Schluss dieses Beitrages eingefügt.

Das angehängte Archiv "Testdateien.zip" enthält:
– den Ordner "Bilddateien";
– das gebrauchsfertige Droplet "DateienUmbenennen_02d.app";
– die Excel-Datei "Farbcodes.xlsx".

Es geht um Kleidungsstücke, deren Definition per Artikelnummer, Farbname und Farbcode.
Die 16 Test-Bilder enthalten je nur ein kleines, farbiges Quadrat (nicht die hübschen Damen der Originale ;-).
In der Excel-Datei ist der Inhalt der Spalten C bis E entfernt (Datenschutz). Zudem werden sie nicht benötigt.

Ausführung:
– Das Exceldokument öffnen;
– gleichfarbige Dateien auf das Droplet ziehen;
– im sich öffnenden Dialog einen Farbnamen wählen;
– mit "OK" bestätigen.

Hinweise:
Das Script macht eine Schleife durch die Dateien, prüft, ob die gewählte Farbe für die aktuelle Artikelnummer vorhanden ist.
Falls ja, holt es den zugehörigen Farbcode und ändert den Namen der Datei nach der vorgegebenen Namenskonvention.

Ist die Datei nicht im Excel-Dokument aufgeführt, wird ihr eine rote Etikette verpasst.

Und wenn die gewählte Farbe für die aktuelle Artikelnummer nicht vorhanden ist, wird eine blaue Etikette zugewiesen.

Die Nummer der ersten Datei ("TA1234_0 16.jpg") ist nicht im Excel-Dokument enthalten. Damit sie eingefärbt wird, muss sie mit mindestens einer zweiten Datei gedroppt werden.

Am sichersten ist, Dateien mit identischer Nummer zu wählen.

Denn: Wenn man "TB1897" und "TB1898" gleichzeitig droppt, kommt man nur mit "black" ungeschoren davon. Weil "grey" oder "olive" nicht für beide Artikelnummern erhältlich sind.


(*

DateienUmbenennen_02d.app

Dateien laut einem Excel-Dokument umbenennen. 

© 25.03.2018 / Hans Haesler, Châtelard 52, CH-1018 Lausanne

*)



on open Dropped_Files

  # Variablen als 'global' definieren

  global artNumList

  global indexList

  global colNameList

  global colCodeList

  

  # die 'delimiters' definieren

  set AppleScript's text item delimiters to "_"

  

  # die Liste der Namen initialisieren

  set nameList to {}

  

  # eine Schleife durch die gedroppten Dateien

  set nFiles to count of Dropped_Files

  repeat with n from 1 to nFiles

    # den Namen der aktuellen Datei der Variablen 'curName' zuweisen.

    tell application "Finder" to set curName to name of (item n of Dropped_Files)

    set tmpName to text item 1 of curName

    if tmpName is not in nameList then

      # den aktuellen Namen ans Ende der Liste anhängen

      set end of nameList to tmpName

    end if

  end repeat

  

  # die 'delimiters' definieren

  set AppleScript's text item delimiters to ", "

  

  tell application "Microsoft Excel"

    tell active sheet

      

      # den Index für die letzte benutzte Zelle der ersten Spalte holen

      set numRows to first row index of (get end (last cell of column 1) direction toward the top)

      

      # die Anzahl prüfen und warnen, falls notwendig

      if numRows is 1 then

        display dialog "Das Dokument scheint leer zu sein." buttons "OK" default button 1 with icon 0

        error number -128

      end if

      

      # die erste Spalte auflisten

      set artNumList to (value of range ("A1:A" & numRows))

      set artNumList to (every text item of (artNumList as string))

      # die zweite Spalte auflisten

      set colCodeList to (string value of range ("B1:B" & numRows))

      set colCodeList to (every text item of (colCodeList as string))

      # die sechste Spalte auflisten

      set colNameList to (value of range ("F1:F" & numRows))

      set colNameList to (every text item of (colNameList as string))

      

    end tell

  end tell

  

  # die 'delimiters' zurücksetzen

  set AppleScript's text item delimiters to {""}

  

  # die Anzahl Elemente zählen

  set nItems to count items of artNumList

  

  # die Indexliste initialisieren

  set indexList to {}

  # eine Schleife durch die Liste der Artikelnummern

  repeat with n from 2 to nItems

    # die aktuelle Artikelnummer

    set curItem to item n of my artNumList

    # wenn die Artikelnummer in der Liste der Namen ist ... 

    if curItem is in nameList then

      # ... den aktuellen Index an die Liste anfügen

      set end of indexList to n

    end if

  end repeat

  

  # die Farbnamen-Liste initialisieren

  set colList to {}

  # eine Schleife durch die Indexliste

  repeat with c from 1 to count of indexList

    # der aktuelle Index

    set curInd to item c of my indexList

    # der entsprechende Farbname

    set curCol to item curInd of my colNameList

    # wenn dieser Name noch nicht in der Liste der Farben ist ...

    if curCol is not in colList then

      # ... die Liste damit ergänzen ...

      set end of colList to curCol

    end if

  end repeat

  

  # die Farbnamen zählen ...

  set nColors to count colList

  if nColors is greater than 1 then

    # ... und den Handler aufrufen, welcher die Namen sortiert

    quickSort(colList, 1, nColors)

  end if

  

  # den Dialog zum Wählen der Farbe anzeigen

  set colorName to (choose from list colList without multiple selections allowed) as string

  # falls Klick auf "Abbrechen": die Ausführung beenden

  if colorName is "false" then error number -128

  

  # die 'delimiters' definieren

  set AppleScript's text item delimiters to "_"

  

  # Variablen initialisieren

  set noMatch to 0

  set noCode to 0

  

  # eine erneute Schleife durch die gedroppten Dateien

  repeat with n from 1 to nFiles

    set okay to false

    set curFile to (item n of Dropped_Files)

    tell application "Finder" to set curName to name of curFile

    # der Name ohne Endung

    set fullName to text 1 thru -5 of curName

    # die Endung

    set curSuf to text -4 thru -1 of curName

    # der Stammname

    set baseName to text item 1 of curName

    # wenn dieser in der Liste der Artikelnummern ist ...

    if baseName is in artNumList then

      set sameName to false

      set indList to {}

      # ... eine Schleife durch die Artikelnummern-Liste

      repeat with m from 2 to nItems

        # die aktuelle Artikelnummer

        set curItem to item m of my artNumList

        # Übereinstimmung prüfen

        if baseName is curItem then

          set sameName to true

          set end of indList to m

        else

          if sameName is true then exit repeat

        end if

      end repeat

      set nInd to count of indList

      repeat with c from 1 to nInd

        set curInd to item c of indList

        if item curInd of my colNameList is colorName then

          # ... den Farbcode speichern

          set curCode to item curInd of my colCodeList

          set okay to true

          exit repeat

        end if

      end repeat

      if okay is true then

        # den neuen Namen zusammensetzen

        set newName to (fullName & "-" & curCode & "%" & colorName & curSuf) as string

        # die Datei umbenennen

        try

          tell application "Finder" to set name of file curFile to newName

        on error

          set noCode to noCode + 1

          try

            tell application "Finder" to set label index of file curFile to 4

          end try

        end try

      else

        # kein Code gefunden: der Datei einen blauen Tag zuweisen

        set noCode to noCode + 1

        tell application "Finder" to set label index of file curFile to 4

      end if

    else

      # Artikelnummer nicht im Exceldokument: der Datei einen roten Tag verpassen

      set noMatch to noMatch + 1

      tell application "Finder" to set label index of file curFile to 2

    end if

  end repeat

  

  # die 'delimiters' zurücksetzen

  set AppleScript's text item delimiters to {""}

  

  # den Anwender informieren

  set nProb to noCode + noMatch

  if nProb is 0 then

    display dialog "Fertig. Alle Dateien sind umbenannt." buttons "OK" default button 1 with icon 1 giving up after 2

  else

    if nProb is 1 then

      display dialog "Achtung: Eine Datei ist nicht umbenannt." buttons "OK" default button 1 with icon 2

    else

      display dialog "Aufgepasst: " & nProb & " Dateien sind nicht umbenannt." buttons "OK" default button 1 with icon 2

    end if

  end if

end open



# der Handler zum Sortieren der Farbnamen

on quickSort(a, L, R)

  script

    property aList : a

  end script

  tell result

    set ctr to L

    set n to R

    set aRef to item L of its aList

    repeat while ctr < n

      repeat while (aRef < item n of its aList) and (ctr < n)

        set n to n - 1

      end repeat

      if n is not ctr then

        set item ctr of its aList to item n of its aList

        set ctr to ctr + 1

      end if

      repeat while (aRef > item ctr of its aList) and (ctr < n)

        set ctr to ctr + 1

      end repeat

      if n is not ctr then

        set item n of its aList to item ctr of its aList

        set n to n - 1

      end if

    end repeat

    set item n of its aList to aRef

    if L < n then

      quickSort(its aList, L, n - 1)

    end if

    if R > ctr then

      quickSort(its aList, ctr + 1, R)

      return its aList

    end if

  end tell

end quickSort

Gruss, Hans

tony_danza

Super,

vielen Dank!

Ich denke so können nun alle Mitleser nachvollziehen über was wir hier die ganze Zeit geredet haben.

Leider fehlt mir gerade die Zeit ein paar Fragen zum Script zu stellen, das werde ich aber machen sobald ich kann.

Manches ist mir nämlich noch nicht so ganz klar.

Trotzdem, bis hierhin ein riesen Dank noch mal Hans!
Dank deiner Hilfe kann ich mich meinem eigentlichen Job wieder widmen und muss nicht mehr so viel Zeit mit Dateien umbenennen verbringen ;)

viele Grüße
tony

tony_danza

Hallo Hans,

zu aller erst, habe ich eine allgemeine Verständnisfrage.

Du verwendest wiederholt Befehle wie:

repeat with n from 1 to nFiles

repeat with n from 2 to nItems

repeat with c from 1 to count of indexList

...

wofür stehen denn die Buchstaben?
In meiner Vorstellung steht n für number, i für index, c für ???

Stimmt das irgendwie? Also haben die Buchstaben irgendeine Bedeutung? Und wenn ja, sind die Buchstaben abhängig vom Inhalt der Liste?

In einer Zeile steht repeat with n from 2. Dem kann ich irgendwie nicht folgen. Warum denn nicht from 1?

Dann hast du folgende Zeile platziert:

# die Anzahl Elemente zählen 

  set nItems to count items of artNumList

Ist es denn notwendig die Anzahl der Elemente zu zählen? Oder dient das nur dazu, sich die Anzahl anzeigen zu lassen wenn man möchte?

# Variablen initialisieren 

  set noMatch to 0 

  set noCode to 0

Was genau bedeuten denn diese Zeilen?

Das findet ja weiter unten im Script noch Verwendung, allerdings werde ich nicht schlau daraus. Könntest du mir das noch bitte erklären?
Ich verstehe in diesen Zeilen

on error 

      set noCode to noCode + 1

eigentlich nur: set noCode to 0 + 1

Wenn ich das mit noCode und noMatch mal verstanden habe, dann werde ich auch schlau aus den nProb Zeilen.

Beim Handler hörts komplett auf. Ich nehme das einfach mal so hin, dass diese Zeilen die Liste sortieren. Das musst du mir auch nicht erklären. Irgendwann werde ich das schon verstehen. Man lernt nie aus ;)

Wäre aber super wenn du mir ein paar Antworten auf meine Fragen geben könntest.

Ich danke dir schon mal und vielen Dank noch mal für deine tolle Version des Scripts! Ich war begeistert zu sehen wie es unter Realbedingung läuft. Schnell und zuverlässig.

viele Grüße
tony

Hans_Haesler

Hallo Tony,

*****
das [#cc0000]n[/#cc0000] in 'repeat with [#cc0000]n[/#cc0000] from 1 to nFiles' ist die Zählervariable.

Die Bedeutung von n kann ein Kürzel für number sein. Bei i wäre es iteration (= lat. "iterare" = "wiederholen").

Das i sollte im Forum vermieden werden, weil [.i] der Code zum Kursivstellen ist. Jetzt scheint es repariert zu sein, aber eine Zeitlang war im geposteten Script das [.i] verschwunden und sämtliche folgende Zeichen waren kursiv.

Der Variablen-Name kann aber auch aus mehreren Zeichen bestehen: 'repeat with [#cc0000]tony[/#cc0000] from 1 to nFiles' :-)

Die Ein-Zeichen-Benennung stammt aus der Ur-Zeit, als ein Script nicht mehr als 32'000 Zeichen umfassen durfte. Das lernte einen, sparsam zu sein ... Bei ein paar Scripts musste ich auf sämtliches Kommentieren verzichten.

*****

In einer Zeile steht repeat with n from 2.

Das Script beginnt mit Reihe zwei, weil in der ersten Reihe Worte wie "Artikelnummer", "Farbcode" usw. stehen.

*****

Ist es denn notwendig die Anzahl der Elemente zu zählen?

Als ich mit dem Entwickeln von AppleScripts begann, wurde einem empfohlen, die Anzahl Elemente vorher, ausserhalb der Schleife zu zählen. Damit dieser Wert nicht ständig, bei jedem Umgang geholt werden muss. Ich konnte damals keine Bremswirkung feststellen und habe den Rat nicht befolgt.

Aber bei einem JavaScript wird die Ausführung beschleunigt. Deshalb übernahm ich dieses Vorgehen auch für AppleScript. Schon nur, dass die Startzeile der Schleife "sauberer" aussieht.

Beim vorliegenden Droplet wird 'nFiles' bei der erneuten Schleife durch die gedroppten Dateien nochmals verwendet.

*****


# Variablen initialisieren

  set noMatch to 0

  set noCode to 0

Diese Zeilen machen genau das, was der Kommentar darüber sagt. Damit der Wert einer Variablen im Script inkrementiert werden kann, muss ihr vorher ein Wert zugewiesen werden.

Deaktiviere mal diese zwei Zeilen (# davorsetzen oder --). Dann kommt bei der Ausführung prompt eine Fehlermeldung.

set noCode to 0 + 1

So ist es. Aber wenn die Null so eingesetzt wird, ist der Wert am Schluss nicht grösser als eins. Auch wenn z.B. vier Dateien nicht umbenannt wurden.

*****

Beim Handler hörts komplett auf. Ich nehme das einfach mal so hin, dass diese Zeilen die Liste sortieren.

Im Oktober 2004 hatte Martin Fischer eine Lösung von mir so kommentiert:

Wow!
Den QuickSort-Handler hast Du aber nicht nur für die PDF-Vereinigung aus dem Ärmel gezogen ...
Da wird mir ganz schwindelig, wenn ich den versuche nachzuvollziehen.
Klasse!

Meine Antwort damals:

Die QuickSort-Routine ist nicht meine Erfindung. Dies ist übrigens die Turbo-Version. Es gibt eine
langsamere. Die schnelle hat den Vorteil, dass sie wirklich schnell ist. Aber in gewissen Fällen
habe ich damit Probleme gehabt. Das Resultat war leer. Ich muss mal versuchen, dies nachzustellen.

Bei der Turbo-Version ist zu Beginn des Handlers ein Script-Objekt definiert. Dessen Einsatz sorgt für viel mehr Geschwindigkeit.

*****

Ich danke dir schon mal und vielen Dank noch mal für deine tolle Version des Scripts! Ich war begeistert zu sehen wie es unter Realbedingung läuft. Schnell und zuverlässig.

Bitte sehr. Ich hoffe, dass es sich weiterhin bewähren wird. Doch wie immer gilt: Einsatz auf eigene Gefahr! Am besten immer vorher mindestens ein Backup der Dateien anlegen.

Gruss, Hans

tony_danza

Hallo Hans,

dank deiner Erklärungen wird mir nun so einiges klar.

Mir war nicht bewusst, dass ich irgendeine Zählervariable verwenden kann, ich dachte die Buchstaben hätten eine Bedeutung, abhängig vom Inhalt.

----
Jetzt machts auch klick bei 'repeat with n from 2'. An die Informationen in der ersten Zeile hatte ich nicht gedacht.

Ich hoffe ich kann daraus lernen und meine zukünftigen Scripts einfacher bzw. schlauer gestalten.

Auf jeden Fall ist AppleScript ein Helferlein den man nicht außer acht lassen sollte. AS kann in jedem Bereich zum Einsatz kommen und ich freue mich auf weitere Automatismen um meine Prozesse zu optimieren.

Vielen Dank für deine schnelle und kompetente Unterstützung.

gruß
tony

Hans_Haesler

Hallo Tony,

bitte sehr.

Nun, für eine "normale" repeat-Schleife braucht es drei Dinge:
– Zählervariable;
– Startwert;
– Stopwert.


repeat with n from 1 to 3

  display dialog n

end repeat

Der Dialog zeigt den Wert von 'n' an.

Eine Schleife kann man auch rückwärts laufen lassen. Das ist notwendig, wenn ein Inhalt verändert wird.


repeat with n from 3 to 1 by -1

  display dialog n

end repeat

Der Zusatz 'by -1' ist zwingend.

Falls Du Dich näher mit AppleScript befassen willst, dann empfiehlt sich ein gezieltes Studium.
Mit einem Buch. Oder einem Kursus.

Für beide findest Du genug Stoff bei Peter Fischer (alias Snow): http://www.fischer-bayern.de/phpBB2/index.php

Rechts oben sind acht Links. Der vierte ist "AppleScript-Bücher".
Rechts Mitte: Ein Link für das ebook "AppleScript für absolute Starter"
Rechts unten findest Du den Workshop (Themen "Dialoge", "Variablen" usw).

Happy learning! :-)

Gruss, Hans

tony_danza

Hallo Hans,

dass eine repeat-Schleife rückwärts laufen kann ist mir neu. Aber vielen Dank für den Tipp! Früher oder später werde ich bestimmt mal darauf zurückgreifen müssen.

Auf der Seite die du verlinkt hast war ich auch schon einige male und das hat mir sehr geholfen.

Bücher zu AppleScript habe ich mir noch nicht gekauft, das wäre aber nicht verkehrt. Bisher habe ich versucht aus Forenbeiträgen zu lernen und aus dem eBook.

Da ich aber nicht aufhören möchte AppleScript zu lernen, sind deine Tipps zu den Büchern bestimmt nicht verkehrt.

Danke dir und viele Grüße
tony

Hans_Haesler

Hallo Tony,

bitte sehr.

Der Zusatz [#cc0000]by[/#cc0000] kann auch in einer vorwärtslaufenden Schleife eingesetzt werden.

Nur [#cc0000]ungerade[/#cc0000] Werte anzeigen:


repeat with n from 1 to 5 by 2

  display dialog n

end repeat

Nur Objekte mit [#cc0000]geraden[/#cc0000] Werten behandeln:


repeat with n from 2 to 6 by 2

  display dialog n

end repeat

Es gibt noch andere Arten von Schleifen (z.B. [#cc0000]with x in aList[/#cc0000] oder eine Konstruktion mit [#cc0000]while[/#cc0000]). Doch diese wirst Du selber finden.

Gruss, Hans

« Vorherige Seite