rechen problem

jekyll

Hallo Allerseits,
ich habe eine Problem mit applescript auf Yosemite (10.10.5) und auch auf al Capitan 10.11.5.
Applescript scheint nicht korrekt zu rechnen wenn es 3 stellen vor und nach dem Komma gibt.

Kann das jemand mir erklären bzw. verifizieren. kann ich das irgendwie um gehen?

set px to {"9138.897755", "9138.897", "913.88977", "283.550", "913.889", "91.388977", "91.38897755"}

set mm to 2.835

set br1 to (item 1 of px as real) / mm

set br2 to (item 2 of px as real) / mm

set br3 to (item 3 of px as real) / mm

set br4 to (item 4 of px as real) / mm

set br5 to (item 5 of px as real) / mm

set br6 to (item 6 of px as real) / mm

set br7 to (item 7 of px as real) / mm

Hans_Haesler

Hallo Sándor,

die Ergebnisse sind doch alle korrekt.

Was erwartest Du denn bei den sieben Divisionen?
Jedes mal nur drei Nachkommastellen?

Gruss, Hans

jekyll

Hallo Hans,
hier sind meine Ergebnise:

{3223.59709171076, 3223.59682539683, 322.359707231041, 1.00017636684303E+5, 3.22359435626102E+5, 32.235970723104, 32.235970917108}

Da rutscht bei mir die Kommastelle nach 2 stellen vorne

Kannst Du auch auf Bild sehen.

Hans_Haesler

Hallo Sándor,

ja, Deine Ergebnisse der beiden "123 Komma 123" sind nicht wie erwartet.

Kannst Du auch auf Bild sehen.

Ein Bild ist nicht zu sehen. Vermutlich hast Du es zwar angehängt, aber nicht auf "Anhang speichern" geklickt.

Was geschieht, wenn Du das folgende Script startest?


set px to {"9138.897755", "9138.897", "913.88977", "283.550", "913.889", "91.388977", "91.38897755"}

set mm to 2.835

set br1 to ((((item 1 of px) / mm) * 1000) div 1) / 1000

set br2 to ((((item 2 of px) / mm) * 1000) div 1) / 1000

set br3 to ((((item 3 of px) / mm) * 1000) div 1) / 1000

set br4 to ((((item 4 of px) / mm) * 1000) div 1) / 1000

set br5 to ((((item 5 of px) / mm) * 1000) div 1) / 1000

set br6 to ((((item 6 of px) / mm) * 1000) div 1) / 1000

set br7 to ((((item 7 of px) / mm) * 1000) div 1) / 1000

Drei Nachkommastellen sind doch ausreichend.

Gruss, Hans

jekyll

Antwort auf: Ein Bild ist nicht zu sehen. Vermutlich hast Du es zwar angehängt, aber nicht auf "Anhang speichern" geklickt.

interessant bei mir zeigt es an.

Antwort auf: Was geschieht, wenn Du das folgende Script startest?

bekomme ich ohne as real Fehler Meldung mit as real ist die Ergebnis gleich.

set px to {"9138.897755", "9138.897", "913.88977", "283.500", "913.889", "91.388977", "91.38897755"}

set mm to 2.835

set br1 to ((((item 1 of px as real) / mm) * 1000) div 1) / 1000

set br2 to ((((item 2 of px as real) / mm) * 1000) div 1) / 1000

set br3 to ((((item 3 of px as real) / mm) * 1000) div 1) / 1000

set br4 to ((((item 4 of px as real) / mm) * 1000) div 1) / 1000

set br5 to ((((item 5 of px as real) / mm) * 1000) div 1) / 1000

set br6 to ((((item 6 of px as real) / mm) * 1000) div 1) / 1000

set br7 to ((((item 7 of px as real) / mm) * 1000) div 1) / 1000

jekyll

hier sind die Bilder als Link:
www.download.siscosep.com/hds/rechnen.pdf

jekyll

Ich bekomme dieser Fehler nur wenn ich das "as real" verwende.

set px to {"283.500", "283.5000"}

set mm to 2.835

set test to round (item 1 of px as real)

set test2 to round item 1 of px

set test3 to round (item 2 of px as real)

set test4 to round item 2 of px

Liefert mir die Ergebnis: test = 284, test2 = 283500, test3 = 284, test4 = 284
Merkwürdig.

Hans_Haesler

Hallo Sándor,

das Konvertieren mit as real braucht es nicht. Weil der Wert durch die Division umgewandelt wird.


set px to {"9138.897755", "9138.897", "913.88977", "283.550", "913.889", "91.388977", "91.38897755"}

set mm to 2.835



set br4 to (item 4 of px) / mm

Die Fehlermeldung kam, weil in meinem Beitrag #4 die Zeile set mm to 2.835 fehlte. Habe ich jetzt korrigiert.

Deine Versionen vom Mac OS X habe ich nicht zur Verfügung. Aber weder mit Mavericks noch mit Sierra kann ich das Problem nachvollziehen.

Falls es Dir sicherer scheint, den Wert umzuwandeln, dann hilft vielleicht eine Multiplikation mit Eins:


set px to {"9138.897755", "9138.897", "913.88977", "283.550", "913.889", "91.388977", "91.38897755"}

set mm to 2.835



set br4 to ((item 4 of px) * 1) / mm

Gruss, Hans

jekyll

Morgen Hans,
leider geht das nur ohne ( ) sobald ich es in den ( ) lege ist meine Ergebnis falsch.

Antwort auf: Die Fehlermeldung kam, weil in meinem Beitrag #4 die Zeile set mm to 2.835 fehlte. Habe ich jetzt korrigiert.

Nein, das habe ich gemerkt :)
Applescript zickt weil das Typ nicht in real gewandelt werden kann. Siehe Bild.

Normaleweise vergesse ich die Wandlung zu Nummer bzw. mache ich es an falsche stelle :(
Ich habe es hierfür gebraucht.

 set pdfGr to do shell script "cat " & quoted form of POSIX path of neueDok & " | egrep -ao '/MediaBox ?\\[ ?[0-9]+ [0-9]+ [0-9]+(\\.[0-9]+)? [0-9]+(\\.[0-9]+)?\\]' | head -1"



set {origDelim, AppleScript's text item delimiters} to {AppleScript's text item delimiters, " "}

set breite to text item 3 of pdfGr

set breite1 to ((((round (text item 3 of pdfGr) rounding up) / mm) * 100) div 1) / 100

set hoehe to text item 4 of pdfGr

set AppleScript's text item delimiters to "]"

set hoehe1 to ((((round (text item 1 of hoehe) rounding up) / mm) * 100) div 1) / 100

set AppleScript's text item delimiters to origDelim

Habe aber mittlerweile das hier gefunden und verwendet :

set {hoehePx, breitePx} to paragraphs of (do shell script "mdls " & quoted form of POSIX path of pdfDok & "| grep -Ei 'kMDItemPage(Height|Width)' | awk '{print $3}'")

Aber nur so bekomme ich korrekte Ergebnisse mit dem man weiter rechnen kann:

set breiteMm to ((((round (breitePx) rounding up) / mm) * 100) div 1) / 100

set hoeheMm to ((((round (hoehePx) rounding up) / mm) * 100) div 1) / 100

jekyll

sorry hier #560822 habe ich die test und test2 vertauscht.

das muss heissen: Liefert mir die Ergebnis: test = 283500, test2 = 284, test3 = 284, test4 = 284
siehe Bild.

Kann mir jemand anders meine Problem bestätigen?

Hans_Haesler

Hallo Sándor,

besteht das Problem auch, wenn Du das Testscript aus meinem Beitrag #4 ab AppleScript-Editor startest? Statt mit dem ScriptDebugger.

Gruss, Hans

jekyll

Leider ja.
Dieser habe ich auf die Rechner von meine Frau gemacht al Captain 10.11.5 im Skript Editor.

www.download.siscosep.com/hds/rechnen5.pdf

kkauer

Das Problem hängt mit den sprachspezifischen Einstellungen zusammen. Auf (d)einem deutschen System ist "." das Tausendertrennzeichen und aus z.B. "1.000" wird bei der Wandlung 1000. Du müsstest also in deinen Strings schon den passenden Dezimaltrenner "," verwenden oder einen anderen Weg/Workaround finden.

jekyll

Hey Karsten,
vielen Dank für die Erklärung!!

Weiss ich nicht ob´s in allen Fällen geht aber mit hochrunden bekomme ich für meine Zwecke einen akzeptablen Ergebnis.
Ist zwar einwenig Größe aber bei der Filmen macht es ja nix :)

set {hoehePx, breitePx} to paragraphs of (do shell script "mdls " & quoted form of POSIX path of pdfDok & "| grep -Ei 'kMDItemPage(Height|Width)' | awk '{print $3}'")

set breiteMm to ((((round (breitePx) rounding up) / mm) * 100) div 1) / 100

set hoeheMm to ((((round (hoehePx) rounding up) / mm) * 100) div 1) / 100

Hans_Haesler

Hallo Karsten,

jetzt, wo Du es sagst ... Hätte ich eigentlich wissen müssen ...

@ Sandor: Dein Dreizeiler funktioniert. Aber durch das Aufrunden sind die Werte leicht erhöht.


set pdfDok to choose file



set mm to 2.835



set {hoehePx, breitePx} to paragraphs of (do shell script "mdls " & ¬

	quoted form of POSIX path of pdfDok & ¬

	"| grep -Ei 'kMDItemPage(Height|Width)' | awk '{print $3}'")

set hoeheMm to ((((round (hoehePx) rounding up) / mm) * 100) div 1) / 100

set breiteMm to ((((round (breitePx) rounding up) / mm) * 100) div 1) / 100



{hoeheMm, breiteMm}

--> {280.07, 220.81}

Wenn die Punkte durch Kommas ersetzt werden, ist das Ergebnis präziser:


set pdfDok to choose file



set mm to 2.835



set {hoehePx, breitePx} to paragraphs of (do shell script "mdls " & ¬

	quoted form of POSIX path of pdfDok & ¬

	"| grep -Ei 'kMDItemPage(Height|Width)' | awk '{print $3}'")



set AppleScript's text item delimiters to "."

set tmpList_1 to every text item of hoehePx as list

set tmpList_2 to every text item of breitePx as list

set AppleScript's text item delimiters to ","

set hoehePx to tmpList_1 as string

set breitePx to tmpList_2 as string



set AppleScript's text item delimiters to {""}



set hoeheMm to ((((hoehePx) / mm) * 100) div 1) / 100

set breiteMm to ((((breitePx) / mm) * 100) div 1) / 100



{hoeheMm, breiteMm}

--> {279.97, 220.67}

Okay, das sind nur Zehntelsmillimeter.

Gruss, Hans

kkauer

Die mdls-Seitenwerte und 2.835 sind ja auch gerundet. ;)

Anyway: Wir "tummeln" uns eh schon in der Shell, also könn(t)en wir dort auch gleich die Probleme angehen/lösen.

Code-Beispiel:
- mdls eingegrenzt, daher kein grep notwendig
- Übergabe der sprachspezifischen Einstellungen (Werte kommen direkt mit Dezimalkomma zurück)
- Umrechnung (_pt/(72/25.4)) inkl. Angabe der gewünschten Nachkommastellen (%.1f = 1 Nachkommastelle)


set userLocale to user locale of (get system info)

set {hoeheMm, breiteMm} to words of (do shell script "mdls -name kMDItemPageHeight -name kMDItemPageWidth -raw '" & POSIX path of pdfDok & "'| LC_NUMERIC=" & userLocale & " xargs -0 -I _pt awk 'BEGIN {printf \"%.1f \",_pt/(72/25.4)}'")

{hoeheMm as real, breiteMm as real}

jekyll

Hallo Karsten,
ich habe Deine Antwort erst jetzt gesehen weil ich mein eigenen Thema nicht auf Themabeobachten gestellt habe. [Blush]

Danke schön.

Werde ich gleich einbauen.

jekyll

Wäre hier die "quoted form of" für den POSIX Path unnützlich?

kkauer

Antwort auf: Wäre hier die "quoted form of" für den POSIX Path unnützlich?

Das "Absichern" des Dateipfads ist generell ratsam und in meinem Code berücksichtigt:

… '" & POSIX path of pdfDok & "' …

Die lange Form funktioniert natürlich auch, in einem solchen Fall finde ich sie aber unnötig "aufgebläht".

… " & quoted form of POSIX path of pdfDok & " …

jekyll

Na schaue her und in letzter Zeit ich bemühe mich noch in meinem scripten es nicht zu vergessen.

Der Distiller will (vielleicht nur bei mir) auch nur "POSIX path of" ohne den "quoted form of" verarbeiten.

Nächste Seite »