Verweise in normalen Text umwandeln

John

Guten Morgen,

ich habe folgendes Problem. Wenn ich einen Text nach Indesign importiere, der sehr viele Fußnoten und Querverweise hat, kann es passieren, das die Fußnoten teilweise zerschossen am Ende des Dokumentes stehen. Meine Frage kann man in dem Worddokument die Verweise in normalen Text umwandeln. Mein System Apple OSC 10.6, Indesign CS4 und Word 2004.

Viele Grüße aus dem Spessart
John

JohanneS.

Moin Kolleginnen und Kollegen,

fast vier Jahre später: gibt es diese Umwandlungsmöglichkeit wirklich nicht, auch nicht in word:mac 2011?
Mein Drumherum ist etwas anders, aber das spielt hier keine Rolle.

Grüße
Johannes

sabine_hamann

Hallo,

die Verweise können mit dem Tastenkürzel umgewandelt werden, dass auch in der Windows-Version funktioniert.
Alles markieren und Befehl-Shift-F9 drücken.

JohanneS.

Moin Sabine,

vielen Dank für die schnelle Antwort, die mir aber leider nicht weiterhilft:
Ich markiere alle Fuß-/Endnoten, drücke die erwähnte Tastenkombination und könnte dann »Feldverknüpfung aufheben« rückgängig machen. Ist das die gewünschte Funktion?
Alles sieht wie vorher aus — und wenn ich zur Kontrolle eine Verweisziffer lösche, dann ist die Note weg. Ist die Verbindung doch nicht gelöst?
Hat das vielleicht mit meiner abschnittsweisen Nummerierung zu tun? Ja, die hatte ich noch nicht erwähnt …

Grüße
Johannes

sabine_hamann

Hallo,

du willst die Fußnotenlinks auch in normale Texte verwandeln. Das geht nur mit Makro.
Ich habs allerdings nicht getestet.

Sub foot2inline()

Dim oFeets As Footnotes

Dim oFoot As Footnote

Dim oRange As Range

Dim szFootNoteText As String



' Grabs the collection of FootNotes

Set oFeets = Word.ActiveDocument.Footnotes



' Iterates through each footnote

For Each oFoot In oFeets

	



	

	szFootNoteText = oFoot.Range.Text

	

	'Start search from beginning of document

	Selection.HomeKey Unit:=wdStory

	Selection.Find.ClearFormatting

  

	With Selection.Find

		.Text = "^f" ' Looks for all footnotes

		.Forward = True

		.Wrap = wdFindStop

	End With

	

	Selection.Find.Execute

	' Delete the footnote

	oFoot.Delete

	

	'Insert the footnote text

	'Here you do whatever format tickles your fancy

	Selection.Text = " [Note: " + szFootNoteText + "] "



	'CHANGE COLOR HERE. Color code is below.

	Selection.Font.Color = 6299648



	'Disables undo to save memory on very large documents.

	ActiveDocument.UndoClear

Next

End Sub

Gruß

JohanneS.

Moin Sabine,

danke für das Makro. Es läuft und wandelt die Fußnoten in nichtnummerierten Text an der (vorherigen) Fußnotenverweisstelle um. So weit so gut, aber das ist nicht das, was ich suche.
Ich muss es genauer beschreiben: Ich habe ein Projekt mit 300 Abschnitten, jeder mit ca. zehn mit Fuß-/Endnoten, die abschnittsweise nummeriert am jeweiligen Abschnittsende im Textfluss stehen müssen.
Lade ich das mit meinem normalen Workflow in mein Layoutprogramm, werden alle dreitausend Noten durchnummeriert und ans Ende gestellt. Das wäre äußerst unhandlich.
Fast genauso unhandlich wäre es, die dreihundert Abschnitte als einzelne Dokumente zu bearbeiten — sie haben gerne nur ein oder zwei Seiten.

Grüße
Johannes

sabine_hamann

Hi Johannes,

in welches Layoutprogramm willst du Datei laden?
Und was heißt Abschnittsweise genau: ein Word-Abschnitt existiert, darin gibt es Fußnoten, die mit 1 bis x nummeriert sind? Dann der nächste Abschnitt gleich aufgebaut.
Dies funktioniert auch nur mit Abschnitten:

Sub UnLinkEndNotes()

Application.ScreenUpdating = False

Dim nRng As Range, eNote As Endnote, nRef As String

With ActiveDocument

  For Each eNote In .Endnotes

    With eNote

      With .Reference.Characters.First

        .Collapse wdCollapseStart

        .InsertCrossReference wdRefTypeEndnote, wdEndnoteNumberFormatted, eNote.Index

        nRef = .Characters.First.Fields(1).Result

        .Characters.First.Fields(1).Unlink

      End With

      .Range.Cut

    End With

 

      Set nRng = eNote.Range.Sections.First.Range



    With nRng

      .Collapse wdCollapseEnd

      .End = .End - 1

      If .Characters.Last <> Chr(12) Then .InsertAfter vbCr

      .InsertAfter nRef & " "

      With .Paragraphs.Last.Range

        .Style = "Endnote text"

        .Words.First.Style = "Endnote Char"

      End With

      .Collapse wdCollapseEnd

      .Paste

      .InsertAfter vbCr

      If .Characters.Last = Chr(12) Then .InsertAfter vbCr

    End With

  Next

  For Each eNote In .Endnotes

    eNote.Delete

  Next

End With

Set nRng = Nothing

Application.ScreenUpdating = True

End Sub

Thobie

Moin, Johannes,

wenn Du mit Fußnoten arbeitest, probiere die XTension für QuarkXPress Foonote/Endnote Management von Virginia Systems aus: http://www.virginiasystems.com/productsbyapp.html.[/url] Eine seeeeehr komfortable Art, Fußnoten aus Word in QuarkXPress zu importieren und zu verwalten.

Ich habe die XTension ausführlich in meinem [Eigenwerbung an]Buch zum wissenschaftlichen Arbeiten mit QXPress[/Eigenwerbung aus] beschrieben, die Beschreibung des Buchs findest Du auf meiner Website.

Grüße

Thobie

JohanneS.

Antwort auf: in welches Layoutprogramm willst du Datei laden?

Das landet nach einem Umweg über qXport von bitmix (Export von Word-Dateien in Text mit Marken) und kräftiger Überarbeitung in TextWrangler (wegen GREP-Suche und ähnlichem) in QuarkXPress.

Antwort auf:
Und was heißt Abschnittsweise genau: ein Word-Abschnitt existiert, darin gibt es Fußnoten, die mit 1 bis x nummeriert sind? Dann der nächste Abschnitt gleich aufgebaut.

Genau richtig verstanden!

Und Dein Makro funktioniert nach einer ersten schnellen Prüfung genau wie gewünscht — morgen sicher ein noch viel größeres Dankeschön!

Grüße
Johannes

JohanneS.

Moin Thobie,

ja, die XTension kenne ich, wenigstens als Demoversion. Sie ist schon vorgemerkt für das nächste Buch mit richtigen Fußnoten.
Hier hilft sie nicht, weil ich keine Fuß- oder Endnoten habe, sondern nur einen einzigen langen Fließtext.
Der hat Abschnitte, die Anmerkungen sind, die aber in den Fluss integriert sind, nicht parallel stehen. Das geht in etwa so: Absatz / Absatz / Anmerkung / Absatz …
Trotzdem Danke für den Hinweis (möge er anderen helfen)!

Grüße
Johannes

JohanneS.

Moin Sabine,

jetzt habe ich mir das Ergebnis genauer angeschaut: wunderbar, alles ist da, wo es sein soll, alles behält seine Formate.
Ganz vielen Dank!

Grüße
Johannes