letzte Seite herausfischen

Harald

Schön, daß AppleScript hier ein eigenes Forum erhalten hat. Ich arbeite viel mit AS, es ist nicht so kompliziert und kann viel und ich kann viele Skripe sehr schnell den jeweiligen Erfordernissen anpassen. - meistens.
Woran ich seit einigen Tagen knoble: Ich habe Bilder von mehrerer Tausend Buchseiten. Die Seiten von jedem Buch sind neu durchnummeriert: _001, _002, _003, …. Nun will ich die jeweils letzte Seite eines Buches in einen separaten Ordner legen, weil an dieser Seite etwas geändert werden soll. Wie kann ich diese letzte Seite mit einem AS herausfischen?

Ich denke mir, das Skript sollte die Namen vergleichen (z.B. vergleiche die letzten drei Ziffern) und wenn die nächste Zahl kleiner als der vorhergehende ist, dann soll die vorhergehende Datei bewegt werden. Leicht erschwerend kommt hinzu, daß die Dateinamen etwas länger sind, also vor der Ordnungszahl ein Blabla_ haben. Aber ich denke, so könnte es gehen, nur, wie formuliert man das als AS?

Gruß
Harald

Hans_Haesler

Hallo Harald,

Gratulation zum Posten des ersten Anfrage am neuen Standort des AppleScript-Forums! :-)

Du sprichst von Seiten. Sind das einzelne Dateien? Von welchem Programm erstellt? Haben diese Dateien kein Suffix?

Ich nehme an, dass die Seiten jedes Buches in einem separaten Ordner liegen. Wo soll der neue Ordner erzeugt werden?

Hast Du schon einen Ansatz des Scripts, welchen Du eventuell posten könntest?

Gruss, Hans

Harald

Danke. Freut mich, den Anfang zu machen.

Jede Seite eine tif-Datei. Mehrere Bücher sind in einem Ordner zusammen, ca. 2-3.000 Seiten.
Jedes Buch ist unterschiedlich lang, das ist die Krux. Wo der neue Ordner liegt ist völlig egal.
Etwa so könnte es aussehen:

set Quellordner to (choose folder with prompt "") as string
tell application "Finder"
set alleOrdner to every folder of folder Quellordner
repeat with einOrdner in alleOrdner
set Dateiliste to every file of einOrdner as alias list

repeat with einDatei in Dateiliste
if name of einDatei contains "_001.tif" then

--move (einDatei-1 of folder "ABC") to folder "letzte_Seite"
-- "Ein Datei-1" ist natürlich Blödsinn!!
end if

end repeat
end repeat
end tell

Hans_Haesler

Hallo Harald,

beginnen wir mit einer [#0000cc]viel einfacheren[/#0000cc] Ausgangslage.

Zum Testen des folgenden Scripts: Bitte erzeuge einen neuen Ordner und kopiere ein halbes Dutzend Dateien hinein.

Dann das Script starten und diesen neuen, "leichten" Ordner wählen. Das Script sollte die Datei mit der höchsten Nummer herausfinden und in den Ordner "Letzte_Seite" verschieben, welcher neben dem gewählten Ordner erzeugt wird.

Das Script erwartet, dass die TIFF-Dateien mit dem Suffix ".tif" versehen sind. Falls sie keine Endung haben, musst Du die Zahlen von 'character 8' und 'character 7' in '4' und '3' ändern.


-- den Quellordner auswählen

set sourceFolder to (choose folder) as Unicode text

-- die Dateinamen auflisten

set allNames to list folder sourceFolder without invisibles

-- eine Liste initialisieren

set numbersList to {}

-- den Texttrenner als Undescore definieren

set AppleScript's text item delimiters to "_"

-- eine Schleife durch die Liste

-- bei jedem prüfen, ob an der richtigen Stelle ein Underscore ist 

-- und dass das folgende Zeichen eine Ziffer ist

-- falls beides zutrifft, das letzte Element an die Liste hängen

repeat with i from 1 to count allNames

  set curName to item i of allNames

  if character -8 of curName is "_" then

    if character -7 of curName is in "0123456789" then

      set end of numbersList to text item -1 of item i of allNames

    end if

  end if

end repeat

-- den Textelement-Trenner zurücksetzen

set AppleScript's text item delimiters to {""}

-- die Liste mit den Nummen zählen und sortieren lassen

set nItems to count numbersList

set aList to quickSort(numbersList, 1, nItems)



-- der Variablen 'lastItem' das letzte Element des Ergebnisses zuweisen

set lastItem to item nItems of aList



-- der Finder holt die Namen aller Dateien, welche mit dem gespeicherten Teil enden

tell application "Finder"

  set lastFile to (get name of every file of folder sourceFolder whose name ends with lastItem)

  -- der Ordner, welcher den Quellordner enthält

  set sourceContainer to container of folder sourceFolder as Unicode text

  -- einen neuen Ordner erzeugen ...

  try

    set newFolder to (make new folder ¬

      at container of folder sourceFolder with properties {name:"Letzte_Seite"}) as Unicode text

  on error

    set newFolder to sourceContainer & "Letzte_Seite"

  end try

  -- ... und die Datei(en) hineinverschieben

  try

    repeat with curFile in lastFile

      move file curFile of folder sourceFolder to folder newFolder with replacing

    end repeat

  end try

end tell



on quickSort(a, l, R)

  script

    property aList : a

  end script

  tell result

    set ctr to l

    set n to R

    set aRef to item l of its aList

    repeat while ctr < n

      repeat while (aRef < item n of its aList) and (ctr < n)

        set n to n - 1

      end repeat

      if n is not ctr then

        set item ctr of its aList to item n of its aList

        set ctr to ctr + 1

      end if

      repeat while (aRef > item ctr of its aList) and (ctr < n)

        set ctr to ctr + 1

      end repeat

      if n is not ctr then

        set item n of its aList to item ctr of its aList

        set n to n - 1

      end if

    end repeat

    set item n of its aList to aRef

    if l < n then

      quickSort(its aList, l, n - 1)

    end if

    if R > ctr then

      quickSort(its aList, ctr + 1, R)

      return its aList

    end if

  end tell

end quickSort

Falls das funktioniert, kannst Du probieren, die Suche auf Unterordner auszudehnen. Aber immer noch im kleinen Stil.

Gruss, Hans

Harald

Hallo Hans ,
vielen Dank für das Skript. Ich hab es gleich mal probiert bekomme aber eine Fehlermeldung:

set aRef to item l of its aList

item 1 of {} kann nicht gelesen werden ??

Hans_Haesler

Hallo Harald,

bitteschön.

Die Fehlermeldung bedeutet, dass keine Dateien gefunden worden sind, welche einen Underscore im Namen an der erwarteten Stelle haben und das nächste Zeichen eine Ziffer ist.

Mit andern Worten: Die Liste ist leer.

Vorbeugend könnte man einen Test einbauen, bevor die Liste zum Sortieren geschickt wird. Ich habe die Zeilen darüber und darunter wiederholt, damit klar ist, wo der Test eingefügt werden muss.


-- die Liste mit den Nummen zählen und sortieren lassen

set nItems to count numbersList

if nItems is 0 then

  display dialog "Keine numerierten Dateien gefunden." buttons "OK" default button 1 with icon 2

  error number -128

end if

set aList to quickSort(numbersList, 1, nItems)

Damit nun das Ergebnis besser wird, musst Du nachschauen, warum die Parameter nicht übereinstimmen.

Wenn die Dateien so benannt sind: "Das_ist_Seite_001.tif", dann sollte das Script funktionieren, so wie es gepostet ist. Es erwartet den Underscore an der achtletzten (= -8) Position des Dateinamens.


  if character -8 of curName is "_" then

    if character -7 of curName is in "0123456789" then

Falls kein Suffix vorhanden ist, steht der Underscore vermutlich an viertletzter Stelle und im Script muss das angepasst werden:


  if character -4 of curName is "_" then

    if character -3 of curName is in "0123456789" then

Gruss, Hans

Harald

Vielen Dank, jetzt funktioniert es. Meine laufenden Nummern sind nicht drei-, sondern vierstellig, also kommen da 9 und 8 rein.

Nun ist die Sache doch etwas komplizierter: Es sind ja mehrere Bücher in dem Ordner und das Skript sollte die letzte Seite von jedem Buch herausfischen. Im Moment fischt es nur die Seite mit der höchsten Zahl ab.

(Daher mein Hinweis: ein neues Buch beginnt immer mit _0001 und die Datei davor ist die letzte des vorhergehenden Buches, ja?)

Gruß
Harald

Hans_Haesler

Hallo Harald,

schön, dass es nun klappt.

Verstehe ich die Struktur richtig? Es gibt [#cc0000]einen[/#cc0000] Hauptordner. Dieser enthält mehrere Unterordner, welche je die Dateien eines Buches enthalten.

Das Script soll nun eine Schleife durch die Unterordner machen, bei jedem die letzte Seite feststellen und diese verschieben.

In einen einzigen Zielordner? Wie kann man denn später die Dateien den Büchern wieder zuordnen?

Gruss, Hans

Harald

Nein, es gibt keine Unterordner. Alles liegt in einem Ordner!

Hans_Haesler

Hallo Harald,

also ... ich verstehe nicht, wie man so arbeiten kann.

Es wäre doch viel einfacher, für jedes Buch einen eigenen Ordner anzulegen. Dann könnten die Dateinamen mit der Nummer beginnen. Es wäre kein Script notwendig, um die letzte Seite zu finden usw.

Zurück zur Aufgabe: Dann kann also der Anfang des Dateinamens jedem Buch zugeordnet werden? Wenn nicht, ist diese Information wenigstens berechenbar untergebracht?

Gruss, Hans

Harald

Hallo Hans,
der Kunde legt die Bilder in eine flache Datenbank ohne Struktur. Er will definitiv keine Ordner. War nicht meine Entscheidung!

Die Bilder eines Buches haben immer denselben Anfang.

Sorry für die Umstände.

Harald

Hans_Haesler

Hallo Harald,

okay. Wieviele Buchstaben der Namensanfänge sind identisch? Sind sie auch durch einen Underscore von weiteren Angaben abgetrennt?

Ideal wäre: Für jedes Buch einen anderen Anfangsbuchstaben.

Gruss, Hans

Harald

Jede Datei hat folgende Struktur:

1234567890123_00001_00020.tif

13Stellen_5Stellen_5Stellen

Titel_Band_Seite

Hans_Haesler

Hallo Harald,

dann bestehen die Dateinamen nur aus Ziffern und Underscores? Vom Suffix abgesehen.

Wichtig zu wissen: Sind die Dateien im Finder schon geordnet?

Wenn ja, dann wäre es manuell leicht möglich, jeweils die letzte eines Buches herauszupicken. Das Script würde einzig ermöglichen, die Dateien schneller einzusammeln. Ist dem so?

Ich werde auf jeden Fall erst im Laufe des Abends eine weitere Lösung posten können.

Gruss, Hans

Harald

Hallo Hans,

ja genau so ist es. Aber mach dir bitte nicht so viel Arbeit. In der Tat, ich scroll durch den Ordner und finde auch so die letzte Seite.Ist zwar etwas umständlich, aber gut zu schaffen.

Falls das jemand locker von Hocker parat gehabt hätte, dann wäre es schön gewesen.
Ih hab ein schlechtes Gewissen, wenn du dir so viel Mühe machst.

Trotdem vielen Dank für deine Aufmerksamkeit.

Gruß
Harald

Hans_Haesler

Hallo Harald,

Deine Aufgabe ist so ... "speziell", dass wohl kaum jemand etwas Gebrauchsfertiges auf dem Rechner hat.

Ein Gegenmittel für das schlechte Gewissen? Da gibt es etwas ganz wirksames: http://hilfdirselbst.org/index1.php?t=Mitgliedschaft%2C+Spende%2C+Werbung&read_category=31 ;-)

Hier ist nun eine Lösung, welche erwartet, dass die ersten dreizehn Zeichen aller Dateien desselben Buches identisch sind.

Zudem wird vorausgesetzt, dass die Dateien im Finder schon sortiert sind. Also müssen auch die mittleren vier Digits entweder identisch oder aufsteigend sein.

Das Script ist nun als benutzerfreundliches Droplet geschrieben. Deshalb muss beim Speichern als Dateiformat nicht die Vorgabe "Script", sondern Programm gewählt werden.

Dann kann es ins Dock gezogen werden. Und zum Ausführen zieht man den Hauptordner auf das Icon des Droplets.

Vorsicht: Zum Testen nur einen Ordner, welcher drei Dateien von drei Büchern enthält, verwenden.

Als erstes wird der Zielordner "Letzte_Seiten" angelegt (falls er noch nicht neben dem Hauptordner existiert).

Dann wird eine Liste der Datei-Namen erstellt. Zur Sicherheit werden sie sortiert. Das kann unter Leopard notwendig sein.

Eine 13stellige dummy-Zahl wird der Variablen [#00cc00]firstDigits[/#00cc00] zugewiesen. Dann geht es in eine Rückwärts-Schleife durch die Namen. Bei jedem Namen werden die ersten dreizehn Zeichen mit dem Teststring verglichen. Stimmt das nicht mehr überein, werden die aktuellen 13 Zeichen an [#00cc00]firstDigits[/#00cc00] übergegeben und der Handler aufgerufen, welcher die Datei in den Zielordner verschiebt.


global newFolder

global sourceFolder



on run

  display dialog "Den Quell-Ordner auf das Icon 

dieses Droplets ziehen." buttons "OK" default button 1 with icon 2

end run



on open (droppedItems)

  -- die Deklaration von 'namesList' als 'global' ist notwendig, 

  -- damit das 'my' (= Geschwindigkeitsschub bei langen Listen) 

  -- in der Schleife akzeptiert wird

  global namesList

  -- der Pfad zum Quell-Ordner

  set sourceFolder to item 1 of droppedItems as Unicode text

  -- warnen, wenn es kein Ordner ist

  if sourceFolder does not end with ":" then

    display dialog "Nur einen *Ordner* auf das Icon ziehen." buttons "OK" default button 1 with icon 0

    error number -128

  end if

  

  tell application "Finder"

    -- der Ordner, welcher den Quellordner enthält

    set sourceContainer to container of folder sourceFolder as Unicode text

    -- darin einen neuen Ordner erzeugen ...

    try

      set newFolder to (make new folder ¬

        at container of folder sourceFolder with properties {name:"Letzte_Seiten"}) as Unicode text

    on error

      set newFolder to sourceContainer & "Letzte_Seiten"

    end try

  end tell

  

  -- die Dateinamen auflisten ...

  set allNames to list folder sourceFolder without invisibles

  -- ... und zählen

  set nNames to count allNames

  if nNames is 0 then

    display dialog "Der Ordner ist leer." buttons "OK" default button 1 with icon 0

    error number -128

  else if nNames is 1 then

    display dialog "Da ist nur eine Datei." buttons "OK" default button 1 with icon 0

    error number -128

  else

    -- zur Sicherheit sortieren lassen

    set namesList to quickSort(allNames, 1, nNames)

  end if

  -- die 13stellige Vergleichs-Variable initialisieren

  set firstDigits to "0000000000000"

  -- eine Rückwärts-Schleife durch die Namen

  repeat with i from nNames to 1 by -1

    -- der aktuelle Name

    set curName to item i of my namesList

    -- die ersten dreizehn Zeichen ...

    try

      set testDigits to text 1 thru 13 of curName

      -- ... mit dem Teststring vergleichen

      -- wenn keine Übereinstimmmung ...

      if testDigits is not equal to firstDigits then

        --- ... der Variablen 'testDigits' den neuen String übergeben ...

        set firstDigits to testDigits

        --- ... und den Handler aufrufen, welcher die Datei verschiebt

        moveFile(curName)

      end if

    end try

  end repeat

end open



-- der Finder verschiebt die aktuelle Datei in den neuen Ordner

on moveFile(curName)

  try

    tell application "Finder" to move file curName of folder sourceFolder to folder newFolder with replacing

  end try

end moveFile



-- der Handler, welcher die Namen sortiert

on quickSort(a, l, R)

  script

    property aList : a

  end script

  tell result

    set ctr to l

    set n to R

    set aRef to item l of its aList

    repeat while ctr < n

      repeat while (aRef < item n of its aList) and (ctr < n)

        set n to n - 1

      end repeat

      if n is not ctr then

        set item ctr of its aList to item n of its aList

        set ctr to ctr + 1

      end if

      repeat while (aRef > item ctr of its aList) and (ctr < n)

        set ctr to ctr + 1

      end repeat

      if n is not ctr then

        set item n of its aList to item ctr of its aList

        set n to n - 1

      end if

    end repeat

    set item n of its aList to aRef

    if l < n then

      quickSort(its aList, l, n - 1)

    end if

    if R > ctr then

      quickSort(its aList, ctr + 1, R)

      return its aList

    end if

  end tell

end quickSort

Gruss, Hans

Harald

Hallo Hans,
da kann ich nichts mehr sagen - einfach perfekt.
Das ist schon eine andere Liga in der du schreibst, als das, was ich von AS verstehe.
Nochmals vielen Dank.

Den Link hab ich gesehen und auch bedient!

Gruß
Harald

Hans_Haesler

Hallo Harald,

bitteschön. Gut, dass es nun wie gewünscht funktioniert.

Und danke für die Blumen. Nun ... ich mache das schon seit mehr als 15 Jahren. Da kommt halt schon einiges an Erfahrung zusammen.

Und schön, dass Du den Wink mit dem Link verstanden hast. ;-)

Gruss, Hans

Harald

Hallo Hans,
nochmals ich. Ich wollte heute mal in die Vollen gehen und hab einen "großen" Ordner mit ca. 7.000 Bildern bearbeiten. Das Programm meldet dann "Stack overflow". Ich hab den Ordner dann immer weiter verkleinert. Die Grenze liegt bei 500 - 600 Bildern. Läßt sich da was machen, daß das Programm auch einen größeren Ordner packt?

Gruß
Harald

Hans_Haesler

Hallo Harald,

beim Durchkämmen von Listen habe ich eine obere Grenze von 8077 festgestellt. Aber das war mit einer Liste, welche im Code des Scripts eingefügt war. Mit einer geladenen Liste waren 9500 kein Problem.

Vielleicht läuft das Fass beim Sortieren über. Deshalb, weil dieses vielleicht nicht notwendig ist: Kommentiere bitte mal den Befehl aus, welcher den Sortierungs-Handler aufruft. Und sieben Zeilen weiter unten das "namesList" durch "allNames" ersetzen. So:


    -- zur Sicherheit sortieren lassen

    -- set namesList to quickSort(allNames, 1, nNames)

  end if

  -- die 13stellige Vergleichs-Variable initialisieren

  set firstDigits to "0000000000000"

  -- eine Rückwärts-Schleife durch die Namen

  repeat with i from nNames to 1 by -1

    -- der aktuelle Name

    set curName to item i of my allNames

Wenn das nichts hilft, dann ... habe ich im Moment keinen Plan. :-(

Gruss, Hans

Nächste Seite »