InDesign: Per AppleScript Bildrahmen-Inhalt verschieben

Hans_Haesler

Hallo Thorsten,

[ dies ist die Fortsetzung des Themas "Per Applescript Bildrahmen-Inhalt verschieben"
http://www.page-online.de/page/forum/viewthread/2992/ ]

Wenn benannte Rahmen angesprochen werden sollen, dann muss man das Script entsprechend anpassen.
Der Vorgabe-Rahmen-Name "Rueckenbild" kann im Dialog geändert werden. Die eingegebene Textkette
wird - mittles 'property' - für die nächste Ausführung gespeichert.

[ Wegen der Page-Forum-Beschränkung auf 6000 Zeichen muss der Code so dargestellt werden ]:

-- den Namen der Ziel-Bildrahmen festlegen
property frameLabel : "Rueckenbild"

-- den Vorgabe-Verschiebe-Wert bestimmen
property aVal : "-2"

-- feststellen, welches Zeichen als Dezimal-Separator definiert ist
set decSep to ""
try
[nbsp] "1.5" as real
[nbsp] set decSep to "."
on error
[nbsp] set decSep to ","
end try

tell document 1 of application "Adobe InDesign CS2"
[nbsp] activate
[nbsp] -- den Anwender bitten, den Rahmen-Namen einzugeben
[nbsp] set frameLabel to text returned of (display dialog "Den Rahmen-Namen eingeben:" default answer frameLabel)
[nbsp] 
[nbsp] -- die Liste der Rahmen zusammenstellen, deren Namen dem eingegebenen entspricht
[nbsp] set frameRefs to every page item whose label is frameLabel
[nbsp] -- wenn die Liste leer ist, den Anwender informieren
[nbsp] if frameRefs is {} then
[nbsp] [nbsp] display dialog "Das aktive Dokument enthält keine Rahmen, welche \"" & frameLabel & "\" heissen." buttons 
[nbsp] [nbsp] [nbsp] "OK" default button 1 with icon 0
[nbsp] [nbsp] -- der folgende Befehl bricht die Ausführung ab
[nbsp] [nbsp] error number -128
[nbsp] end if
[nbsp] 
[nbsp] -- den Anwender bitten, den Versatz-Wert einzugeben
[nbsp] set aVal to text returned of (display dialog "Die Bilder verschieben um:" default answer aVal)
[nbsp] -- die Variable 'dVal' initialisieren
[nbsp] set dVal to ""
[nbsp] -- eine Schleife, um die Eingabe zu prüfen
[nbsp] repeat with i from 1 to count of aVal
[nbsp] [nbsp] -- der Variablen 'curChar' das aktuelle Zeichen der Eingabe zuweisen[nbsp] 
[nbsp] [nbsp] set curChar to character i of aVal
[nbsp] [nbsp] -- wenn dieses Zeichen einem der möglichen entspricht, wird es an 'dVal' angehängt
[nbsp] [nbsp] if curChar is in "-0123456789" then
[nbsp] [nbsp] [nbsp] set dVal to dVal & curChar
[nbsp] [nbsp] else if curChar is in ".," then
[nbsp] [nbsp] [nbsp] set dVal to dVal & decSep
[nbsp] [nbsp] else
[nbsp] [nbsp] [nbsp] display dialog "Die Eingabe enthält ein ungültiges Zeichen:
" & curChar buttons "OK" default button 1 with icon 0
[nbsp] [nbsp] [nbsp] error number -128
[nbsp] [nbsp] end if
[nbsp] end repeat
[nbsp] -- die Textkette 'dVal' in eine Zahl verwandeln
[nbsp] set dVal to dVal as real
[nbsp] 
[nbsp] -- eine Schleife durch die Rahmen, um den Versatz zuzuweisen
[nbsp] repeat with curFrame in frameRefs
[nbsp] [nbsp] tell curFrame
[nbsp] [nbsp] [nbsp] try
[nbsp] [nbsp] [nbsp] [nbsp] set {y1, x1, y2, x2} to geometric bounds of graphic 1
[nbsp] [nbsp] [nbsp] [nbsp] set properties of graphic 1 to {geometric bounds:{y1 + dVal, x1 + dVal, y2 + dVal, x2 + dVal}}
[nbsp] [nbsp] [nbsp] end try
[nbsp] [nbsp] end tell
[nbsp] end repeat
[nbsp] 
[nbsp] display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell

Gruss, Hans

Anonym

Hallo Hans,
vielen Dank. Habe ne Menge gelernt und werde das Script als Nachschlagewerk für zukünftige nutzen.

Gruß, Thorsten

Hans_Haesler

Hallo Thorsten,

bitteschön. Ich musste das Script recht allgemein halten, da ich nicht genau
weiss, welche Aufgabe Du ausführen möchtest.

Und wie immer gilt: Es sollten noch der eine oder der andere Test eingebaut
werden, damit bei Problemen die Fehler abgefangen und verständlichere
Meldungen gezeigt werden können.

Gruss, Hans

Anonym

Hallo Hans,
das Script hilft bei der Anlage eines Schriftzuges auf einem Buchrücken bzw. auf den Seitenkanten. Auf jedem der -[nbsp] in diesem Fall 480 -[nbsp] Blätter wird das Bild positioniert und um die Seitenstärke verschoben. Da das Buch in mehrere Dokumente unterteilt ist, besteht die Möglichkeit, einen Anfangswert für den Versatz einzugeben.

--Wähle das Rückenbild per dialog oder fix (!"alias")
--set myNameFile to "74GB:20050904_19.jpg"
set myNameFile to choose file with prompt "Klick das Rueckenbild!"

tell document 1 of application "Adobe InDesign CS2"
--lege das rückenbild auf einen auf jeder seite bzw. montagefläche zu erzeugenden benannten Rahmen
--repeat with i from 1 to count of spreads
tell every spread
set myRueckenRectangle to make rectangle with properties {geometric bounds:{20, 292, 190, 299}, label:"Rueckenbild"}
try
--place alias (myNameFile) on myRueckenRectangle
place (myNameFile) on myRueckenRectangle
end try
end tell
--end repeat

-- Zweiter Teil: Verschiebe den Bildinhalt
set frameLabel to "Rueckenbild"
-- die Liste der Rahmen zusammenstellen, deren Namen dem eingegebenen entspricht
---- Den Anwender bitten, den Anfangs-Wert einzugeben
set anfangswert to text returned of (display dialog "Das Bild im ersten Rückenbildrahmen versetzen um:
Bitte positiven Wert mit Punkt statt Komma." default answer "0.0") as real
-- set anfangswert to 0
set seitenstaerke to anfangswert
repeat with i from 1 to count of spreads
set frameRefs to (every page item of spread i whose label is frameLabel)
-- eine Schleife durch die Rahmen, um den Versatz zuzuweisen
repeat with curFrame in frameRefs
tell curFrame
try
set {y1, x1, y2, x2} to geometric bounds of graphic 1
set properties of graphic 1 to {geometric bounds:{y1, x1 - seitenstaerke, y2, x2 - seitenstaerke}}
end try
end tell
end repeat
set seitenstaerke to (seitenstaerke + 0.12)
end repeat
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1

end tell

Grüße

Thorsten

Hans_Haesler

Hallo Thorsten,

ja, mit einem konkreten Beispiel ist die Sache viel klarer!

Kleiner Hinweis: Die Zeile, in welcher der Anwender höflich gebeten wird, doch ja den Punkt
zu verwenden, kann weggelassen werden. Aber um eine eventuelle Fehlermeldung zu vermeiden,
muss -[nbsp] wie oben gezeigt -[nbsp] der 'text returned' Zeichen um Zeichen geprüft werden.

Kommt ein Punkt oder ein Komma vor, dann setzt das Script an dessen Stelle jenes Zeichen in
die neue Textkette, welches am Anfang als Dezimalseparator festgestellt worden ist.

Somit gelingt das Umwandeln 'as real'. Im Ergebnis wird in beiden Fällen ein Punkt stehen.

Gruss, Hans